1 READ F$: IF F$ = "" THEN PRINT "patch successful": END
2 OPEN F$ FOR RANDOM AS 1 LEN = 1: FIELD 1, 1 AS X$: READ A
3 READ O$: FOR I = 1 TO LEN(O$) STEP 2: A = A + 1: GET 1, A
4 X = ASC(X$ + CHR$(0)): C$ = MID$(O$, I, 2): IF C$ = "??" THEN 6
5 IF X <> VAL("&h" + C$) THEN PRINT "wrong version of "; F$: STOP
6 NEXT: READ A, N$: FOR I = 1 TO LEN(N$) STEP 2: A = A + 1
7 LSET X$ = CHR$(VAL("&h" + MID$(N$, I, 2))): PUT 1, A: NEXT
8 READ A$: IF A$ <> "" THEN A = VAL(A$): READ O$: GOTO 3
9 GOTO 1: REM [file,[compadr,compdata/??,patchadr,patchdata,]*,]*,
10 DATA PC64Win.exe,&h41066,80CB08F645FC??740380CB10,&h4106C,03,,

